CardName=Blank ; No cards found yet

Innie=%1% ; Filename of SdA deck passed to the program

GetKeyState, ShiftBypass, LShift ; Check if LShift is being held down
If ShiftBypass = D
  Outie=CardDeck.txt ; If so, output file is CardDeck.txt
Else
  StringReplace, Outie, Innie, dck, txt ; Otherwise, it’s the same as the original name except with .txt not .dck

Loop, Read, %Innie% ; Parse each line of the SdA deck
{
  ThisLine:=A_LoopReadLine
  StringSplit, XMLPieces, ThisLine, <> ; Split it up into pieces

  ; Find Quantity, Side (Fellowship/Shadow/Site/Frodo/Ring), and Name
  If XMLPieces2=Quantity
    CardQuantity:=XMLPieces3
  Else If XMLPieces2=Side
    CardSide:=XMLPieces3
  Else If XMLPieces2=Name
    CardName:=XMLPieces3

  If CardName <> Blank ; We found a card name
  {
    StringReplace, CardName, CardName, * ; Remove any * (Unique mark not used by Lackey)

    ; Sort and convert cards according to side
    If CardSide=Fellowship ;
      FellowshipCards=%FellowshipCards%%CardQuantity%`t%CardName%`n
    Else If CardSide=Shadow
      ShadowCards=%ShadowCards%%CardQuantity%`t%CardName%`n

    Else If CardSide=Site
    {
      StringSplit, SiteName, CardName, () ; Separate site number and name
     
      ; Strip extra space on some SdA sites
      StringLeft, CheckForSpace, SiteName3, 1
      If CheckForSpace=%A_Space%
        StringTrimLeft, SiteName3, SiteName3, 1
     
      ; Keep site numbers for now
      SiteCards=%SiteCards%%SiteName2%%CardQuantity%`t%SiteName3%`n
    }

    Else If CardSide=Frodo
      StartingCards=%StartingCards%%CardQuantity%`t%CardName%`n
    Else If CardSide=Ring
      StartingCards=%StartingCards%%CardQuantity%`t%CardName%`n

    CardName=Blank ; Reset cardname until we find the next one
  }
}

; Sort each alphabetically by title
Sort, FellowshipCards, P3
Sort, Shadowcards, P3
Sort, StartingCards, P3

Sort, SiteCards ; Sort sites by number if relevant

; Trim site numbers
Loop, Parse, SiteCards, `n
{
  ThisLine:=A_LoopField
  StringTrimLeft, ThisLine, ThisLine, 1
  SortedSiteCards=%SortedSiteCards%%ThisLine%`n
}

; Trim extra newlines from sites and starting decks
StringTrimRight, SortedSiteCards, SortedSitecards, 1
StringTrimRight, StartingCards, StartingCards, 1

FileDelete, %Outie% ; Delete output file if it exists

FileAppend, %FellowshipCards%%ShadowCards%Sites:`n%SortedSiteCards%Starting:`n%StartingCards%, %Outie%

StringSplit, SiteName, CardName, () ; Separate site number and name
StringLeft, SiteName2, SiteName2, 1